$Assumptions=c>0&&c<1

(*operator deformed by s conjugated to the time-integrated occupation*)

Wn={{-c,1-c},{c,-(1-c)-s}};Wn//MatrixForm

Eigenvalues[Wn]

Eigenvalues[Wn]/.s->0

ψn[s_]=Simplify@Eigenvalues[Wn][[2]]

cnum=1/3;

Plot[{ψn[s]/.c->cnum,-c s/.c->cnum},{s,-1,2},Frame->True,FrameLabel->{"s","ψ(s)"},LabelStyle->Directive[FontSize->20],PlotStyle->{Automatic,{Thin,Dashed,Purple}},PlotRange->{Full,{-.3,.6}}]

Simplify[-ψn'[0]]

Plot[{-ψn'[s]/.c->cnum},{s,-1.5,2},Frame->True,Axes->True,PlotRange->{Full,{-.1,.9}},Frame->True,FrameLabel->{"s","-ψ'(s)"},LabelStyle->Directive[FontSize->20]]

(*some checks*)

Simplify[-ψn'[0]]

(*determination of the entropy π(ρ)*)

(* (SuperStar[s])(ρ) verifies -ψn'[(SuperStar[s])(ρ)]==ρ *)
sols=Simplify[Solve[-ψn'[s]==ρ,s]]

FullSimplify[sols/.ρ->c]

(*The results depends on whether c>1/2 or c<1/2 ; one choses c<1/2*)
FullSimplify[sols/.ρ->c,c<1/2]

sstar[ρ_]=s/.sols[[1]]

pi[ρ_]=FullSimplify[ψn[sstar[ρ]]+ ρ sstar[ρ],c<1/2&&ρ>0&ρ<1&&ρ<1/2]

(*with some help one can simplify further*)

(pi[ρ]/.(-1+ρ)ρ->-σ/.(-1+c)c->-σc/.-(-1+ρ)ρ->σ)/.(-1+ρ)->-σ/ρ

pi[ρ_]=Simplify[(pi[ρ]/.(-1+ρ)ρ->-σ/.(-1+c)c->-σc/.-(-1+ρ)ρ->σ)/.(-1+ρ)->-σ/ρ,σ>0&&σc>0]/.{σ->ρ(1-ρ),σc->c(1-c)}

(*final result*)

Plot[pi[ρ]/.c->cnum,{ρ,0,1},Frame->True,FrameLabel->{"ρ","π(ρ)"},LabelStyle->Directive[FontSize->20],PlotRange->{Full,{-.7,.1}}]

(*Comparison to Gaussian fluctuations*)

piGauss[ρ_]=Simplify[-(ρ+ψn'[0])^2/( 2ψn''[0])]

Simplify[Series[pi[ρ],{ρ,c,2}]]

Plot[{pi[ρ]/.c->cnum,piGauss[ρ]/.c->cnum},{ρ,0,1},Frame->True,FrameLabel->{"ρ","π(ρ)"},LabelStyle->Directive[FontSize->20],PlotRange->{Full,{-.7,.1}},PlotStyle->{Automatic,{Dashed,Purple}}]

(*operator deformed by s conjugated to the activity K*)

WK={{-c,Exp[-s](1-c)},{Exp[-s]c,-(1-c)}};WK//MatrixForm

Eigenvalues[WK]

Eigenvalues[WK]/.s->0

ψK[s_]=Simplify@Eigenvalues[WK][[2]]

cnum=1/3;

Plot[ψK[s]/.c->cnum,{s,-1,2},Frame->True,FrameLabel->{"s","ψ(s)"},LabelStyle->Directive[FontSize->20]]

Plot[-ψK'[s]/.c->cnum,{s,-.9,2},Frame->True,Axes->True,PlotRange->{Full,{-.1,.9}},FrameLabel->{"s","-ψ'(s)"},LabelStyle->Directive[FontSize->20]]

(*some checks*)

Simplify[-ψK'[0]]

(*and indeed the average escape rate is*)
Simplify[c(1-n)+(1-c)n/.n->c]