Table of Contents¶
Agrégation externe de mathématiques, texte d’exercice diffusé en 2012¶
Épreuve de modélisation, option informatique¶
- Ce notebook Jupyter, utilisant OCaml (via le kernel Ocaml), est une correction non officielle d'un texte de modélisation pour l'option informatique de l'agrégation externe de mathématiques.
- Il s'agit du texte public2012-D5.
- Cette tentative de correction partielle a été rédigée par Lilian Besson (sur GitHub ?, sur Bitbucket ?), et est open-source.
- J'avais déjà rédigé une solution, pendant ma propre préparation à l'agrégation en 2013/2014, voir ce fichier.
Retour ?
- Vous avez trouvé un bug ? → Signalez-le moi svp !, merci d'avance.
- Vous avez une question ? → Posez la svp !
Pour l'option informatique (D) de l'agrégation de mathématiques (en France).¶
Attention : ce document ne prétend pas être LA correction du texte, mais un exemple de solution.
Je me suis inspiré des propositions d'implémentations rédigées par les élèves qui ont préparé ce texte en 3h50 le lundi 13 mai 2019.
Exercice requis¶
L'exercice de programmation était en page 2/8 du texte, après l'explication du problème et de l'algorithme de Bresenham.
Écrire un programme permettant de représenter le segment $[A B]$, où $A= (a_1,a_2)$ et $B=(b_1,b_2)$, en suivant l'algorithme de Bresenham. On supposera que $a_1<b_1$, $a_2 \leq b_2$ et que la pente $\alpha$ de la droite est inférieure à $1$. La sortie du programme sera la liste des couples $(x_i,y_i)$ des points représentant le segment.
Attention, on rappelle que le rapport du jury précise explicitement que dans les exercices de programmation liste de … signifie liste OU tableau, au choix du candidat ou de la candidate.
Choix de structure de données¶
Soit $n = b_1 - a_1 \in\mathbb{N}$. Ici, on connaît à l'avance le nombre de points que doit contenir la solution, donc utiliser un tableau de $n+1$ points est une bonne idée.
En OCaml¶
On va préférer :
let segment = Array.make (n+1) (a1, a2) in
...
for i = 1 to n do
let xi, yi = ..., ... in
segment.(i) <- (xi, yi);
done
à :
let segment = ref [(a1, a2)] in
...
for i = 1 to n do
let xi, yi = ..., ... in
segment := (xi, yi) :: !segment;
done
En Python¶
On pourrait de même créer un tableau dès le début. On va préférer :
segment = [ (0,0) for i in range(n+1) ]
segment = [ (0,0) ] * (n+1)
...
for i in range(n):
xi, yi = ..., ...
segment[i] = (xi, yi)
à :
segment = [ (a1, a2) ]
...
for i in range(n):
xi, yi = ..., ...
segment.append(xi, yi)
Réponse¶
On utilise un type point pour représenter les points de coordonées entières $(x, y) \in\mathbb{Z}^2$, cela facilitera l'affichage des signatures :
type point = (int * int);;
let point_a : point = (0, 0)
and point_b : point = (4, 3);;
type segment = point array;;
La fonction suivante renvoie un tableau de $n+1$ points, représentant le segment $[a, b]$ obtenus avec l'algorithme de Bresenham.
- Complexité temporelle : $\mathcal{O}(n)$
- Complexité mémoire : $\mathcal{O}(n)$, où n = b1 - a1. (dans tous les cas)
let bresenham (a : point) (b : point) : segment =
let a1, a2 = a
and b1, b2 = b in
let n = b1 - a1 in
let segment_ab = Array.make (n+1) a in
let alpha_normalisee = b2 - a2 in (* pente normalisée, ie alpha*n dans *)
let erreur = ref 0 in
let y_tilde = ref a2 in
for i = 1 to n-1 do
if 2 * (!erreur + alpha_normalisee) <= n then
erreur := !erreur + alpha_normalisee
else begin
erreur := !erreur + alpha_normalisee - n;
y_tilde := !y_tilde + 1;
end;
segment_ab.(i) <- (a1 + i, !y_tilde);
done;
segment_ab.(n) <- b;
segment_ab
;;
On fait quelques exemples...¶
bresenham (0, 0) (5, 2);;
bresenham (0, 0) (5, 5);;
Si une hypothèse n'est pas vérifié¶
On vérifie que l'ordre des arguments est important, le programme exige que $a_1 < b_1$ et $a_2 \leq b_2$ :
bresenham (0, 0) (-5, 2);;
Si la pente est $\alpha>1$, le programme ne fait pas ce qu'on espérait, car ses hypothèses ne sont pas respectées :
bresenham (0, 0) (0, 2);;
Bonus : deux autres méthodes (droites inférieure et supérieure)¶
Ce n'est pas exigé dans le texte, mais on pouvait facilement implémenter la méthode qui longe la droite au plus près inférieurement, et au plus près supérieurement.
Pour la première, c'est assez facile et on peut aussi travailler uniquement avec des entiers :
- Complexité temporelle : $\mathcal{O}(n)$
- Complexité mémoire : $\mathcal{O}(n)$, où n = b1 - a1. (dans tous les cas)
let au_plus_pres_inferieurement (a : point) (b : point) : segment =
let a1, a2 = a
and b1, b2 = b in
let n = b1 - a1 in
let segment_ab = Array.make (n+1) a in
let alpha_normalisee = b2 - a2 in (* pente normalisée, ie alpha*n dans *)
for i = 1 to n-1 do
(* on laisse la division entière faire la partie inférieure *)
segment_ab.(i) <- (a1 + i, (alpha_normalisee * i + a2 * (b1-a1)) / (b1 -a1));
done;
segment_ab.(n) <- b;
segment_ab
;;
Sur les mêmes exemples, on voit la différence, quand la pente est $\alpha<1$ :
bresenham (0, 0) (5, 2);;
au_plus_pres_inferieurement (0, 0) (5, 2);;
bresenham (0, 0) (5, 5);;
au_plus_pres_inferieurement (0, 0) (5, 5);;
Pour la droite au plus près supérieurement, on va illustrer l'utilisation d'arithmétique flottante et de la fonction
ceil- Complexité temporelle : $\mathcal{O}(n)$
- Complexité mémoire : $\mathcal{O}(n)$, où n = b1 - a1. (dans tous les cas)
ceil;;
let ceil_to_int x = int_of_float (ceil x);;
let au_plus_pres_superieurement (a : point) (b : point) : segment =
let a1, a2 = a
and b1, b2 = b in
let n = b1 - a1 in
let segment_ab = Array.make (n+1) a in
let alpha = (float_of_int (b2 - a2)) /. (float_of_int n) in (* pente normalisée, ie alpha*n dans *)
for i = 1 to n-1 do
segment_ab.(i) <- (a1 + i, ceil_to_int ((float_of_int a2) +. alpha *. (float_of_int i)));
done;
segment_ab.(n) <- b;
segment_ab
;;
Sur les mêmes exemples, on voit la différence, quand la pente est $\alpha<1$ :
bresenham (0, 0) (5, 2);;
au_plus_pres_superieurement (0, 0) (5, 2);;
bresenham (0, 0) (5, 5);;
au_plus_pres_superieurement (0, 0) (5, 5);;
Autres bonus : calculer le mot binaire codant les déplacements¶
Si on utilise par exemple la droite longeant au plus près inférieurement, la fonction suivante renvoie la suite des déplacements horizontaux ou diagonaux pour longer le segment $[a, b]$.
type mot_binaire = bool array;;
let deplacements (a : point) (b : point) : mot_binaire =
let a1, a2 = a
and b1, b2 = b in
let n = b1 - a1 in
let mot_binaire_ab : mot_binaire = Array.make n false in
let alpha_normalisee = b2 - a2 in (* pente normalisée, ie alpha*n dans *)
let y0 = ref 0 and y1 = ref 0 in
for i = 1 to n do
y0 := !y1;
(* on laisse la division entière faire la partie inférieure *)
y1 := (alpha_normalisee * i + a2 * (b1-a1)) / (b1 -a1);
mot_binaire_ab.(i-1) <- !y0 != !y1;
done;
mot_binaire_ab
;;
Sur les mêmes exemples, on voit la différence, quand la pente est $\alpha<1$ :
au_plus_pres_inferieurement (0, 0) (5, 2);;
deplacements (0, 0) (5, 2);;
Le mot renvoyé est $(0 0 1 0 1)$, comme prévu.
Et si la pente est $\alpha=1$, le mot sera $(11111)$.
au_plus_pres_inferieurement (0, 0) (5, 5);;
deplacements (0, 0) (5, 5);;
Conclusion¶
Attention¶
Les 35/40 minutes de passage au tableau ne doivent PAS être uniquement consacrée à la présentation de vos expériences sur l'ordinateur !
Il faut aussi :
- faire une introduction générale (citer des mots clés),
- présenter le plan de votre présentation,
- introduire les notations, les objectifs et les résultats donnés par le texte,
- prouver ou exposer des développements theoriques personnels (à choisir parmi la liste proposée, mais pas seulement),
- etc.
C'est tout pour aujourd'hui les amis ! Allez voir d'autres notebooks si vous voulez.